/** 
  * Mandel Path 
  * by Xavier Gouchet (2008) 
  * xavier.gouchet@gmail.com
  */
  
// aerea settings
float top = 1.25;
float bottom = -1.25;
float left = -2.25;
float right = 1.0;

// mndlbrt settings
int iter = 96;
float step = 0.004;

// display settings
int width, height; 

// grids
boolean[][] mset;

// bg Image
PImage bg;
PFont fontA = createFont("Arial", 10);

void setup(){
	// Init frame settings
	width  = (int) ( (right - left) / step );
	height = (int) ( (top - bottom) / step );
	size(width,height);
	background(0);
	mset = new boolean[width][height];
	bg = new PImage(width,height);
        textFont(fontA,10);
        smooth();

	// compute Mandelbrot set
	for (int i=0; i<width; i++){
		for (int j=0; j<height; j++){
			// N = Mē+ C
			float Cx = (i * step) + left;
			float Cy = (j * step) + bottom;
			float Mx = 0, My = 0, Nx = 0, Ny = 0;
			
			// init grid for this value
			mset[i][j] = true;
                        color black = color(0,0,0);
                        bg.set(i,j,black);
			
			// mandelbrot main loop
			for (int k = 0; k<iter; k++){
				// get N 
				Nx = (Mx*Mx) - (My*My) + Cx;
				Ny = (2*Mx*My) + Cy;
				
				// test Nē
				float z = sqrt((Nx*Nx + Ny*Ny));
				if ( z > 2){
					mset[i][j] = false;
					
					// colorize 
					float c = ((iter-k)*96)/iter;
					color col = color(c,c,c);
					bg.set(i,j,col);
					break;
				}
				// decal 
				Mx = Nx;
				My = Ny;
			}
		}
	}
}

void draw(){
	background(bg);

	// N = Mē+ C
	float Cx = (mouseX * step) + left;
	float Cy = (mouseY * step) + bottom;
	float Mx = 0, My = 0, Nx = 0, Ny = 0;
	
	
	int Mi = mouseX, Mj = mouseY, Ni = 0, Nj = 0;
	// mandelbrot main loop
	for (int k = 0; k<iter; k++){
		// get N 
		Nx = (Mx*Mx) - (My*My) + Cx;
		Ny = (2*Mx*My) + Cy;

                String s = "Point : " + str(Nx) + ";" + str(Ny);
                text(s,10,((k+1)*14));
		Ni = (int) round( (Nx - left)/step);
		Nj = (int) round( (Ny - bottom)/step);
		
                int col = ((iter-k)*255) / iter;
		stroke(col,96,0);
		if (mset[mouseX][mouseY])
			stroke(0,64,col);
		line(Ni,Nj,Mi,Mj);
		
		// test Nē
		float z = sqrt((Nx*Nx + Ny*Ny));
		if ( z > 2)
			break;
		
		// decal 
		Mx = Nx;
		My = Ny;
		Mi = Ni;
		Mj = Nj;
	}

}