/* Mandelbrot Demo
 * by Xavier Gouchet, 2008
 * http://www.xgouchet.fr
 * xavier.gouchet@gmail.com
 */
 
int maxIter = 24;
float top = 1.5;
float bottom = -1.5;
float left = -2.0;
float right = 1.0;
float step = 0.01;
int w, h;
int time; 

int[][] iter;

void setup(){
  // compute frame size
  w = (int) ( (right - left) / step );
  h = (int) ( (top - bottom) / step );
  
  // Init App Settings
  time = 0;
  size(w,h);
  frameRate(12);
  iter = new int[w][h];
  
  // Mandelbrot Init
  for (int i=0; i<w; i++){
    for (int j=0; j<h; j++){
      float x = (i*step) + left;
      float y = (j*step) + bottom;
      float a = 0; float b = 0;
      iter[i][j] = maxIter;
      for (int c = 0; c<maxIter; c++){
        float an = (a*a) - (b*b) + x;
        float bn = (2*a*b) + y;
        if ((an*an + bn*b) > 4){
          iter[i][j] = c;
          break;
        }
        a = an; 
        b = bn;
      }
    }
  }
}

void draw(){
  time++;
  time = time%maxIter;
  background(0);
  stroke(255);
  for (int i=0; i<w; i++){
    for (int j=0; j<h; j++){
      if (abs(iter[i][j] - time) <= 2){
        point(i,j);
      }
    }
  }
}