PImage pattern;
int side = 31;
int thickness = 10;
Cell[][] grid; 
void setup(){
  size(310,310);
  frameRate(12);

  // load qr pattern image
  pattern = loadImage("qrcode.png");
  grid = new Cell[side][side];

  for (int i=0; i<side;i++){
    for (int j=0; j<side;j++){
      int c = pattern.get(i,j);
      boolean state = red(c) > 0;
      boolean fixed = green(c) > 0;

      if (!fixed) 
        state =  (random(0,1) > 0.5);

      grid[i][j] = new Cell(state,fixed);
    }
  }

  noStroke();
}

void draw(){
  background(0);
  preProcessGrid();
  processGrid();
  renderGrid();

}

void preProcessGrid(){
  for (int i=0; i<side;i++){
    for (int j=0; j<side;j++){
      grid[i][j].preProcess(getNeighbours(i,j));
    }
  }
}

void processGrid(){
  for (int i=0; i<side;i++){
    for (int j=0; j<side;j++){
      grid[i][j].process();
    }
  }
}

void renderGrid(){
  for (int i=0; i<side;i++){
    for (int j=0; j<side;j++){
      fill(0);
      if (grid[i][j].isAlive())
        fill(255);
        
      rect(i*thickness,j*thickness,thickness,thickness);
    }
  }
}

int getNeighbours(int x, int y){
  int n = 0;
  for (int i=-1; i<=1; i++){
    if (((x+i)<0)||(x+i)>=side)
      continue;

    for (int j=-1; j<=1; j++){
      if (((y+j)<0)||(y+j)>=side)
        continue;
      if ((i!=0)||(j!=0)){
        if (grid[x+i][y+j].isAlive())
          n++;
      }
    }
  }
  return n;
}


void mousePressed() {
 for (int i=0; i<side;i++){
    for (int j=0; j<side;j++){
       grid[i][j].randomize();
    }
  }
}